MODULE EventNumber;

IMPORT Fmt, Text, EventNumberF;
FROM EventProtocol IMPORT Word32;

REVEAL
  T = EventNumberF.Private BRANDED "EventNumber.T" OBJECT
  OVERRIDES
    init := Init;
    inc := Inc;
    dec := Dec;
    compare := Compare;
    fmt := Format;
  END;

PROCEDURE Init(self: T; t: T := NIL): T =
  BEGIN
    IF t # NIL THEN
      self.lo := t.lo;
      self.hi := t.hi;
    ELSE
      self.lo := 0;
      self.hi := 0;
    END;
    RETURN self;
  END Init;

PROCEDURE Inc(self: T) RAISES {Overflow} =
  BEGIN
    IF self.lo = LAST(Word32) THEN
      IF self.hi = LAST(Word32) THEN
        RAISE Overflow;
      ELSE
        self.lo := 0;
        INC(self.hi);
      END;
    ELSE
      INC(self.lo);
    END;
  END Inc;

PROCEDURE Dec(self: T) RAISES {Overflow} =
  BEGIN
    IF self.lo = FIRST(Word32) THEN
      IF self.hi = FIRST(Word32) THEN
        RAISE Overflow;
      ELSE
        self.lo := LAST(Word32);
        DEC(self.hi);
      END;
    ELSE
      DEC(self.lo);
    END;
  END Dec;

PROCEDURE Format(self: T; base: Fmt.Base) : Text.T =
  BEGIN
    RETURN Fmt.Unsigned(self.hi, base) & "." & Fmt.Unsigned(self.lo, base);
  END Format;

PROCEDURE New(t: T := NIL): T =
  BEGIN
    RETURN NEW(T).init(t);
  END New;

PROCEDURE Compare(p1, p2: T): [-1..1] =
  BEGIN
    IF p1.hi > p2.hi THEN
      RETURN 1;
    ELSIF p1.hi < p2.hi THEN
      RETURN -1;
    ELSIF p1.lo > p2.lo THEN
      RETURN 1;
    ELSIF p1.lo < p2.lo THEN
      RETURN -1;
    END;
    RETURN 0;
  END Compare;

BEGIN
END EventNumber.