<*PRAGMA LL*>

UNSAFE MODULE TrestleOnX EXPORTS TrestleOnX, TrslOnXF;

IMPORT X, TrestleComm, VBT, XClientF, Thread, VBTClass, TrestleClass;

PROCEDURE Dpy (t: Display): X.DisplayStar =
  BEGIN
    RETURN t.dpy
  END Dpy;

PROCEDURE Drawable (v: VBT.T): X.Drawable =
  BEGIN
    LOOP
      IF v = NIL THEN RETURN X.None END;
      TYPECASE v.upRef OF
        XClientF.Child (ch) => IF ch # NIL THEN RETURN ch.w END
      ELSE                      (* skip *)
      END;
      v := v.parent
    END
  END Drawable;

PROCEDURE Cage (v: VBT.T): X.Drawable =
  BEGIN
    LOOP
      IF v = NIL THEN RETURN X.None END;
      TYPECASE v.upRef OF
        XClientF.Child (ch) => IF ch # NIL THEN RETURN ch.xcage END
      ELSE                      (* skip *)
      END;
      v := v.parent
    END
  END Cage;

PROCEDURE EventHook (t: Display; p: EventProc): EventProc =
  VAR res := t.eventHook;
  BEGIN
    t.eventHook := p;
    RETURN res
  END EventHook;

<*INLINE*> PROCEDURE Enter (t: Display) RAISES {TrestleComm.Failure} =
  BEGIN
    Thread.Acquire(t);
    IF t.dead THEN Thread.Release(t); RAISE TrestleComm.Failure END
  END Enter;

<*INLINE*> PROCEDURE Exit (t: Display; deltaCoverage: [-1 .. 1] := 0)
  RAISES {TrestleComm.Failure} =
  BEGIN
    TRY
      IF t.dead THEN RAISE TrestleComm.Failure END;
      XClientF.AdjustCoverage(t, deltaCoverage)
    FINALLY
      Thread.Release(t)
    END
  END Exit;

PROCEDURE Init() =
  BEGIN
    Visibility := VBT.GetMiscCodeType("Visibility");
  END Init;

BEGIN
END TrestleOnX.