MODULE SwitchVBT;

IMPORT ButtonVBT, FeedbackVBT, Filter, MultiClass, MultiFilter, VBT;

REVEAL
  T = Public BRANDED OBJECT
      OVERRIDES
        init     := Init;
        callback := Callback;
        pre      := Pre;
        post     := Post;
        cancel   := Cancel;
      END;

  MC = MultiClass.Filter BRANDED OBJECT
       OVERRIDES
         succ    := Succ;
         pred    := Succ;
         replace := Replace;
       END;

PROCEDURE Init (v: T; f: FeedbackVBT.T): T =
  BEGIN
    EVAL ButtonVBT.T.init (v, f, Action);
    MultiClass.Be (v, NEW(MC));
    MultiClass.BeChild (v, MultiFilter.Child (f));
    RETURN v
  END Init;

PROCEDURE Callback (<* UNUSED *>          v : T;
                    <* UNUSED *> READONLY cd: VBT.MouseRec) =
  BEGIN
  END Callback;

PROCEDURE Action (         selfAsButtonVBT: ButtonVBT.T;
                  READONLY cd             : VBT.MouseRec ) =
  BEGIN
    NARROW (selfAsButtonVBT, T).callback (cd)
  END Action;

PROCEDURE Pre (v: ButtonVBT.T) =
  BEGIN
    FeedbackVBT.Excited (Filter.Child (v));
  END Pre;

PROCEDURE Post (v: ButtonVBT.T) =
  BEGIN
    FeedbackVBT.Normal (Filter.Child (v));
  END Post;

PROCEDURE Cancel (v: ButtonVBT.T) =
  BEGIN
    FeedbackVBT.Normal (Filter.Child(v));
  END Cancel;

PROCEDURE Replace (m: MC; <* UNUSED *> ch: VBT.T; new: VBT.T) =
  BEGIN
    WITH switch = m.vbt,
         feedback = Filter.Child (switch) DO
      EVAL MultiFilter.Replace (feedback, new);
    END
  END Replace;

PROCEDURE Succ (m: MC; ch: VBT.T): VBT.T =
  BEGIN
    WITH switch = m.vbt,
         feedback = Filter.Child (switch) DO
      IF ch = NIL THEN
        RETURN MultiFilter.Child (feedback);
      ELSE
        RETURN NIL
      END;
    END
  END Succ;

BEGIN
END SwitchVBT.